global_settings { max_trace_level 50 }

#include "colors.inc"
#include "textures.inc"

camera {location <0,2.5,-40>
look_at <0,2.5,0>}
light_source { <2, 20, -40> color rgb <.2,.2,.4> }

//background stars
#declare r = seed(1); 
#declare i=0;
#while (i<1000)           
 object {sphere{<rand(r)*200-100,rand(r)*130-50,120> rand(r)*0.2 
 pigment {White} finish {Luminous} }}
#declare i=i+1;
#end


//transparent texture
#declare none = pigment {color rgbt <1,1,1,1>}
 
//aurora medium
#declare blue_light= media {
      emission .5
      intervals 15
      samples 1, 10
      confidence 0.9999
      variance 1/1000
      density {
      gradient y 
        turbulence <.1,.07,.1> scale <1,1,1>
        color_map {
          [0.0 color rgb <0, 0,0>]
          [0.25 color rgb <0, 0,0>]
          [0.3 color rgb <.15,.4 , .8>]  
          [0.4 color rgb <.05, .12, .2>]
          [1.0 color rgb <0, 0,0>]
        }}}  
        
//distant fog texture
#declare fogtexture=texture{ pigment{
      gradient y 
         color_map {
          [0.0 color rgbt <.1,0,0,0>]
          [0.1 color rgbt <.1,0,0,0>]  
          [0.15 color rgbt <.1,0,0,.4>]
          [0.2 color rgbt <.1,0,0,1>]
          [0.5 color rgbt <.1,0,0,1>]
          [1.0 color rgbt <.1,0,0,1>]
        }}}

//not a sunset, but just the last bit of daylight
#declare sunsetmedia=media{
     emission .12
      intervals 10
      samples 1, 10
      confidence 0.9999
      variance 1/1000
      density {
      gradient y 
         color_map {
          [0.0 color rgbt <.7, .7,1,0>]
          [0.1 color rgbt <.4,.4,.6,.3>]  
          [0.2 color rgbt <.2,.2,.35,.7>]
          [0.3 color rgbt <0,0,.2,1>]
          [1.0 color rgbt <0,0,.2,1>]
        }}}   
 
  
//csg elements for aurora  
#declare element1=
 difference { 
 cylinder {<0,0,0>  <0,1,0> 5 hollow }
 cylinder {<0,-0.1,0> <0,1.1,0> 4 hollow scale 1.29*z }  
  box{<-21,-0.2,-21><21,1.2,0>}
} 

#declare element2=
 difference { 
 cylinder {<0,0,0>  <0,1,0> 5 hollow }
 cylinder {<0,-0.1,0> <0,1.1,0> 4 hollow scale 1.255*z } 
  box{<-21,-0.2,-21><21,1.2,0>}
  box{<-21,-0.2,-.1><0,1.2,21>}}

//elements grouped together             
#declare group= 
union {        
object {element1 hollow  rotate y*90  translate <0,0,0>   }
object {element1 hollow  rotate y*270  translate <-0.01,0,9.> }
object {element1 hollow  rotate y*270 translate <-0.01,0,-9.> }
object {element2 scale z*2 hollow  rotate y*90 translate <0.,0,18.> }}

#declare aurora=
object {group 
interior {media{blue_light  translate <0,0,0>}}
pigment {none}} 


//show the last bit of daylight 
object{box{<-200,0,100><200,200,104>
}hollow interior {media{sunsetmedia scale y*230 translate -y*20}}
pigment {none}translate -y*42 }

//attenuate the starlight near horizon
object{box{<-200,0,105><200,200,109>
}texture {fogtexture scale y*260 translate -y*15} translate -y*50}

// aurora
object {aurora scale <4,50,2> rotate y*20 rotate x*20 translate <0,0,20>}

//mountains
object {height_field { tga "berg.tga" smooth scale <50,9,30>
 translate<-25,-1.2,-60> } pigment {White}}